Percentage Price Oscillator I

PPO:= ((Mov(C,12,E ) - Mov(C,26,E))/Mov(C,12,E))*100;
Trigger:= Mov(PPO,9,E);
PPO; Trigger;

Percentage Price Oscillator II

PPO:= ((Mov(C ,12,E ) - Mov(C,26,E))/Mov(C,12,E))*100;
Trigger:= Mov(((Mov(C ,12,E ) - Mov(C,26,E))/Mov(C,12,E))*100,9,E);
PPO;
Trigger;

Pivot Points

R#2:=((H+L+C)/3) - (2*((H+L+C)/3) - H) +
(2*((H+L+C)/3) - L);
R#1:=2*((H+L+C)/3) - L;
S#1:=2*((H+L+C)/3) - H;
PP:=(H+L+C)/3;
S#2:=((H+L+C)/3) - (((2*((H+L+C)/3) -
L)-(2*((H+L+C)/3) - H)));

R#2;
R#1;
PP;
S#1;
S#2;

Pivot Price Indicator

{The calculation for the new day are calculated from the High (H), low (L) and close (C) of the previous day.}

{P = Pivot Price}
(H + L + C)/3;
{R1 = 1st Resistance}
(2*((H + L + C)/3))-L;
{S1 = 1st Support}
(2*((H + L + C)/3))-H;
{R2 = 2nd Resistance }
(((H + L + C)/3)-((2*((H + L + C)/3))-H))+((2*((H + L + C)/3))-L);
{S2 = 2nd Support}
((H + L + C)/3)-(((2*((H + L + C)/3))-L)-((2*((H + L + C)/3))-H))

Plotting Forward Days

TC:=Input("Tomorrow's close",0.001,100000,1);
MAP:=Input("Moving Average Period",2,144,55);
MA1:=Mov(C,MAP,E);
EPX:=2/(MAP+1);
MA2:=(TC*EPX)+(MA1*(1-EPX));
ValueWhen(1,Cum(1)=LastValue(Cum(1)),MA2)

Polarized Fractal Efficiency

Mov(If(C,>,Ref(C,-9),Sqr(Pwr(Roc(C,9,$),2) + Pwr(10,2)) /
Sum(Sqr(Pwr(Roc(C,1,$),2)+1),9),-
Sqr(Pwr(Roc(C,9,$),2) + Pwr(10,2)) /
Sum(Sqr(Pwr(Roc(C,1,$),2)+1),9))*100,5,E)

Point & Figure Indicator

{ by Adam Hefner }
{Note: this will plot the high of the"x" and low of the "o" on a barchart}

{box value}
BS1:=Input("Box Size ?",.1,100,1);
{reversal amount}
RS1:=Input("Reversal Amount ?",1,10,3)*BS1;
{box high calculation}
BH1:=(Int(H/BS1))*BS1;
{box low calculation}
BL1:=If(((Int(L/BS1))*BS1)=L,
{then}L,
{else}((Int(L/BS1))*BS1)+BS1);
{reversal calculation}
DH1:=If((BL1>=Ref(BL1,-1))AND
((BH1-RS1)>=Ref(BL1,-1)),
{then}1,
{else}0);
DL1:=If((BH1<=Ref(BH1,-1))AND
((BL1+RS1)<=Ref(BH1,-1)),
{then}1,
{else}0);
{Determine market direction}
{NOTE: The value of D1=
1="trend up"
-1="trend down"}
D1:=If(DH1=1 AND DL1=1,
{then}If(BarsSince(Ref(DH1=1,-1))=
BarsSince(Ref(DL1=1,-1)),
{then}If(BarsSince(
ValueWhen(3,DH1=1,DH1))<
BarsSince(
ValueWhen(3,DL1=1,DL1)),
{then}-1,
{else}1),
{else}If(BarsSince(Ref(DH1=1,-1))<
BarsSince(Ref(DL1=1,-1)),
{then}1,
{else}-1)),
{else}If(BarsSince(DH1=1)<BarsSince(DL1=1),
{then}-1,
{else}1));
{time since market reversed}
DH:=BarsSince(D1=1);
DL:=BarsSince(D1=-1);
{ plot high and low }
PH1:=HighestSince(1,DH=1,BH1);
PL1:=LowestSince(1,DL=1,BL1);
PH2:=ValueWhen(1,DH>0,PH1);
PL2:=ValueWhen(1,DL>0,PL1);
PH2;
PL2;

Preferred (Slow) Oscillator Di Napoli

FK:=((C - LLV(L,8))/(HHV(H,8) - LLV(L,8)))* 100;
FD:=If(Cum(1)+1<(3+2),FK,
If(Cum(1)+1=(3+2),Mov(FK,LastValue(3),S),PREV+((1/3)*(FK-PREV))));
STO:=If(Cum(1)+1<(3+2),FD,
If(Cum(1)+1=(3+2),Mov(FD,LastValue(3),S),PREV+((1/3)*(FD-PREV))));
FD;STO;

Presto's Magic Box

Periods:=Input("periods",1,260,100);
Topbox:=If(Ref(H,-3)>=Ref(HHV(H,Periods),-4) AND Ref(H,-2)<Ref(H,-3)
AND Ref(H,-1)<Ref(H,-3) AND H< Ref(H,-3),Ref(H,-3),PREVIOUS);
Botbox:=If(Ref(H,-3)>=Ref(HHV(H,Periods),-4) AND Ref(H,-2)<Ref(H,-3)
AND Ref(H,-1)<Ref(H,-3) AND H< Ref(H,-3),LLV(L,4),PREVIOUS);
Botbox;
Topbox;

PVT Normalized I

{Fast Line}
Mov((PVT()-LLV(PVT(),19))/(HHV(PVT(),19)-LLV(PVT(),19)), 5, S);

{Slow Line}
Mov(Mov((PVT()-LLV(PVT(),19))/(HHV(PVT(),19)-LLV(PVT(),19)), 5, S),3,S);

PVT Normalized II

{Short Line}
ShortMA1:= Input("Enter Shorter M. Average Periods for Short Line",1,32000,5);
LongMA1:= Input("Enter Shorter M. Average Periods for Short Line",1,32000,19);
HiLo:= Input("Enter periods for HHV and LLV - Short Line",1,32000,19);
mat:=Input("MA Type:S,E,W,T",1,4,4); {1=S,2=E,3=W,4=T}
If(mat=1,Mov(Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA1,S),ShortMA1,S),
If(mat=2,Mov(Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA1,E),ShortMA1,E),
If(mat=3,Mov(Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA1,W),ShortMA1,W),
If(mat=4,Mov(Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA1,T),ShortMA1,T),0))));

{Slow Line}
LongMA2:= Input("Enter Shorter M. Average Periods for Slow Line",1,32000,5);
mat2:=Input("MA Type:S,E,W,T",1,4,1); {1=S,2=E,3=W,4=T}
If(mat2=1,Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA2,S),
If(mat2=2,Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA2,E),
If(mat2=3,Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA2,W),
If(mat2=4,Mov((PVT()-LLV(PVT(),HiLo))/
(HHV(PVT(),HiLo)-LLV(PVT(),HiLo)),LongMA2,T),0))));

Price Volume Trend Stochastic

{Fast line}
;Mov((PVT()-LLV(PVT(),19)) / (HHV(PVT(),19)-LLV(PVT(),19)), 5, S)

{Slow Line}
;Mov(Mov((PVT()-LLV(PVT(),19)) / (HHV(PVT(),19)-LLV(PVT(),19)), 5, S),3,S)

PRO-GO - Williams-Professionals

Prof:=Mov(O - C,7,S);
(((Sum( Prof - LLV(Prof,7),7)) / Sum((HHV(Prof,7) - LLV(Prof,7)),7)))*100;
25;
75;

PRO-GO - Williams-Public

Public:= Mov(O - Ref(C,-1), 7, S);
((((Sum( Public - LLV(Public,7),7)) / Sum((HHV(Public,7) - LLV(Public,7)),7)))*100);
75;
25;

Pro Go II

PublicBUY:=Mov(O-Ref(C,-1),14,E);
ProBUY:=Mov((C-O),14,E);
ProBuy; {red line}
PublicBUY; {green line}
ProBuy-PublicBUY >0; {Show crossovers}

Pro-Go III

pds:=21;
public:=Mov(O-Ref(C,-1),pds,E)*200;
pro:=Mov(C-O,pds,E)*200;
public;
pro;
0